logger.info("applying SSDT bamboo/artifactory Gradle Settings")

buildscript {
    repositories {
        maven { url 'https://docker.ssdt.io/artifactory/gradle-plugins' }
    }
    dependencies {
        classpath(group: 'org.jfrog.buildinfo', name: 'build-info-extractor-gradle', version: '2.1.0')
    }
}

apply {
    apply plugin: org.jfrog.gradle.plugin.artifactory.ArtifactoryConfigurationsPlugin
}

artifactory {
    contextUrl = 'https://docker.ssdt.io/artifactory'
    publish {
        def isFeature = gradle.branchStream == 'feature'
        repository {
            repoKey = isFeature ? 'libs-branches-local' : 'libs-snapshots-local'
            // Publisher username and password
            // Sub projects must provide these values via command line or properties file
            username = artifactoryUsername
            password = artifactoryPassword
            maven = !isFeature
            if (isFeature) {
                ivy {
                    ivyLayout = "${gradle.branchHash}/[organization]/[module]/ivy-[revision].xml"
                    artifactLayout = "${gradle.branchHash}/[organization]/[module]/[revision]/[module]-[revision](-[classifier]).[ext]"
                    mavenCompatible = false
                }
            }
        }
        defaults {
            publishBuildInfo = true
            publishArtifacts = true
            publishPom = false
            publishIvy = true
            properties = [ 'ssdt-branch.branchName': gradle.branchName.replaceAll('/','-'), 'ssdt-branch.branchStream': gradle.branchStream ]
        }
    }
}

subprojects {
    apply {
        apply plugin: org.jfrog.gradle.plugin.artifactory.ArtifactoryConfigurationsPlugin
    }
}