logger.info("applying SSDT bamboo/artifactory Gradle Settings")

buildscript {
    repositories {
//        maven { url 'https://docker.ssdt.io/artifactory/gradle-plugins' }
        mavenCentral()
    }
    dependencies {
        classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.28.4"
    }
}

//apply plugin: org.jfrog.gradle.plugin.artifactory.ArtifactoryConfigurationsPlugin

allprojects {
    apply plugin: org.jfrog.gradle.plugin.artifactory.ArtifactoryPlugin
    apply plugin: 'ivy-publish'
    apply plugin: 'java'

    afterEvaluate {
        publishing {
            publications {
                ivyJava(IvyPublication) {
                    from components.java
                }
            }
        }
    }
}

artifactory {
    contextUrl = 'https://docker.ssdt.io/artifactory'
    publish {
        def isFeature = gradle.branchStream == 'feature'
        repository {
            repoKey = isFeature ? "libs-branches-local/${project.gradle.branchHash}" : 'libs-snapshots-local'
            if (gradle.branch.isRelease()) {
                repoKey = "libs-releases-local"
            }
            // Publisher username and password
            // Sub projects must provide these values via command line or properties file
            username = artifactoryUsername
            password = artifactoryPassword
            if (isFeature) {
                ivy {
                    ivyLayout = "[organization]/[module]/ivy-[revision].xml"
                    artifactLayout = "[organization]/[module]/[revision]/[module]-[revision](-[classifier]).[ext]"
                    mavenCompatible = true
                }
            }
        }
        defaults {
            publications('ivyJava')
            publishBuildInfo = true
            publishArtifacts = true
            publishPom = false
            publishIvy = true
            properties = [ 'ssdt-branch.branchName': gradle.branchName.replaceAll('/','-'), 'ssdt-branch.branchStream': gradle.branchStream ]
        }
    }
}